#!ipxe

#dhcp

echo
echo ==========================================
echo Welcome to Kanotix iPXE network boot image
echo ==========================================
echo

prompt --timeout 2500 Press any key to continue... ||

set release spitfire

cpuid --ext 29 && set bit 64 || set bit 32

set variant1 LXDE
set variant2 LXDE-openbox
set variant3 awesome
set variant4 KDE
set variant5 KDE-gfxdetect

menu Please choose variant
item ${variant1} ${variant1}
item ${variant2} ${variant2}
item ${variant3} ${variant3}
#iseq ${bit} 64 && item ${variant4} ${variant4} ||
#iseq ${bit} 64 && item ${variant5} ${variant5} ||
item ${variant4} ${variant4}
item ${variant5} ${variant5}
choose --timeout 5000 variant

iseq ${variant} KDE-gfxdetect && set extra gfx=on && set variant KDE-special ||
iseq ${variant} LXDE-openbox && set extra nocompiz && set variant LXDE ||
iseq ${variant} awesome && set extra awesome && set variant LXDE ||

set server http://134.169.192.30/project/kanotix/pxe/boot/${release}-${bit}-${variant}
set iso http://134.169.192.30/project/kanotix/pxe/iso/kanotix${bit}-${release}-nightly-${variant}.iso

set lang1 utc=no timezone=Europe/Berlin locales=de_DE.UTF-8,en_US.UTF-8 keyboard-layouts=de keyboard-variants=nodeadkeys
set lang2 utc=yes locales=en_US.UTF-8
set lang3 utc=no timezone=Europe/Zurich locales=de_CH.UTF-8,en_US.UTF-8 keyboard-layouts=ch

set lang ${lang1}

echo Choose language:
echo
echo 1. German / Deutsch (default)
echo 2. English
echo 3. German - Swiss / Deutsch - Schweiz
echo
echo -n -- ->

read lang-choice
echo
set lang ${lang${lang-choice}}

set boot1 httpfs=${iso}
#set boot1 httpfs=${server}/filesystem.squashfs
set initrd1 ${server}/initrd.img

set boot2 fetch=${iso}
#set boot2 fetch=${server}/filesystem.squashfs
set initrd2 ${server}/initrd.img

set boot ${boot1}
set initrd ${initrd1}

echo Choose bootmethod:
echo
echo 1. httpfs (default)
echo 2. fetch (like toram)
echo
echo -n -- ->

read boot-choice
echo
set boot ${boot${boot-choice}}
set initrd ${initrd${boot-choice}}

kernel ${server}/vmlinuz quiet boot=live config ${lang} ${boot} ${extra} 
initrd ${initrd}

boot